座標法と数式処理ソフト maxima で断面性能の計算式を求めるやり方を紹介します。
座標法でも 形状寸法を変数とすれば 計算式を 求めることができます。多角形に限られますが 積分をする必要はありません。
数式処理ソフトを利用すれば 多角形の頂点の座標を定義するだけで 断面積から主軸の角度まで算定することができます。いまのところ、円弧や放物線は 折れ線に置き換える必要があるのですが、今後の研究によって 合理的な手法が提案されてくると思われます。
多角形の断面性能の計算式は
となります。座標に数値を代入すれば 断面性能が算定できます。
ただし
座標 = [x1, y1], [x2, y2], [x3, y3], …, [xn, yn]
Ax = S, Ix = Jx, Iy = Jy, Ixy = Jxy
図心回りの2次モーメント
Ixc = Ix - Ax * gy ** 2
Iyc = Iy - Ax * gx ** 2
図心回りの相乗モーメント
Ixyc = Ixy - Ax * gx * gy
Xc軸からの主軸の角度 α
α = atan2(2 * Ixyc, Iyc - Ixc) / 2
Σ は i = 1, n-1
座標は閉鎖形の頂点でそれを結ぶ線が交差しないようにする
※参考文献
○材料力学本論 / 前澤・吉峯訳 / コロナ社 付録2 平面図形の諸元
○建造力学 / 谷口著 / 裳華房 第20章 断面の主軸
台形 です。
Mery で以下のスクリプトを ファイル名 "100-6.bat" で保存して実行してください。
/* trapezoid
@echo off & cls
path C:\maxima-5.47.0\bin;%path%
type %0 | maxima --very-quiet
pause
goto:eof
*/
Pt : matrix([0, 0], [c, h], [c+a, h], [b, 0])$
n : length(Pt)-1$
x : col(Pt, 1)$
y : col(Pt, 2)$
Ax : sum( (s[i] : x[i+1] * y[i] - x[i] * y[i+1]) / 2, i, 1, n)[1]$
gx : sum(s[i] * (x[i] + x[i+1]) / (6 * Ax), i, 1, n)[1]$
gy : sum(s[i] * (y[i] + y[i+1]) / (6 * Ax), i, 1, n)[1]$
Ix : sum(s[i] * ( (y[i] + y[i+1]) ^ 2 + y[i] ^ 2 + y[i+1] ^ 2) / 24, i, 1, n)[1]$
Iy : sum(s[i] * ( (x[i] + x[i+1]) ^ 2 + x[i] ^ 2 + x[i+1] ^ 2) / 24, i, 1, n)[1]$
Ixy : sum(s[i] * ( (x[i] + x[i+1]) * (y[i] + y[i+1]) + x[i] * y[i] + x[i+1] * y[i+1]) / 24, i, 1, n)[1]$
Ixc : Ix - Ax * gy ^ 2$
Iyc : Iy - Ax * gx ^ 2$
Ixyc : Ixy - Ax * gx * gy$
alpha : if Ixyc = 0 then 0 else atan2(2 * Ixyc, Iyc - Ixc) / 2$
print("area")$
print(" Ax =", factor(Ax))$
print("elastic center")$
print(" gx =", factor(gx))$ print(" gy =", factor(gy))$
print("moment of inertia of area")$
print(" Ix =", factor(Ix))$ print(" Iy =", factor(Iy))$
print("centrifugal moment of area")$
print(" Ixy =", factor(Ixy))$
print("moment of inertia of area by elastic center")$
print(" Ixc =", factor(Ixc))$ print(" Iyc =", factor(Iyc))$
print("centrifugal moment of area by elastic center")$
print(" Ixyc =", factor(Ixyc))$
print("principal axis of area")$
print(" alpha =", factor(alpha))$
quit()$
計算式は
となります。
多角形に円弧が含まれても、円弧部分を補正すれば精算値を返すことが可能です。たとえば 円弧の中点をとって[始点,中点,終点]で三角形の面積を求めると 左回りなら正、逆なら負、どちらでもないなら直線と判断できます。この性質を利用すれば 円弧は正確に評価できます。
次回は 正多角形 を取り上げます。