外部変形は データのやり取りをテキストファイルで行うので プログラム言語は 自由に選ぶことができます。図形は機能的かつシンプルなため、数多くのユーザーに受け入れられています。
vbscriptで線の複線を引く
:vbscriptで線の複線を引く
@echo off
if not exist %~dp0eval.vbs echo ExecuteGlobal WScript.StdIn.ReadAll > %~dp0eval.vbs
for /f "delims=:" %%n in ('findstr /n "^#!" %0') do (
copy jwc_temp.txt myfiles > nul
(
: echo Option Explicit
echo On Error Resume Next
: echo On Error GoTo 0
more +%%n %0
) | cscript //nologo %~dp0eval.vbs > jwc_temp.txt
)
goto:eof
REM #jww
REM #1ln 線を指示してください。
REM #2 基準点を指示してください。
REM #bz
REM #e
#!この次の行からプログラムを書いてください
'1)正規表現
Dim re
Set re = New RegExp
re.IgnoreCase = True '大文字と小文字を区別しない
re.Global = True '文字列全体を検索する
function reSplit(str)
re.Pattern = "[ ]+"
reSplit = Split(Trim(re.Replace(str," ")))
end function
function reTest(pat, str)
re.Pattern = pat
reTest = re.Test(str)
end function
'4)ユーザ定義関数
function atan2(y, x)
if x = 0 then
atan2 = atn(1) * 2 * sgn(y)
else
atan2 = atn(y / x)
end if
if x < 0 then
if y < 0 then
atan2 = atan2 - atn(1) * 4
else
atan2 = atan2 + atn(1) * 4
end if
end if
end function
function hypot(x, y)
hypot = sqr(x * x + y * y)
end function
function lnlength(x) '線長
if typename(x) = "String" then x = Split(Trim(x))
lnlength = hypot(x(2) - x(0), x(3) - x(1))
end function
function lnslope(x) '線角
if typename(x) = "String" then x = Split(Trim(x))
lnslope = atan2(x(3) - x(1), x(2) - x(0))
end function
function ln_hpdist(x, p)
if typename(x) = "String" then x = Split(Trim(x))
if typename(p) = "String" then p = Split(Trim(p))
ln_hpdist = lnlength(Array(p(0), p(1), x(0), x(1))) * sin( lnslope(x) - lnslope(Array(p(0), p(1), x(0), x(1))) )
end function
function lnmove(x, b)
if typename(x) = "String" then x = Split(Trim(x))
if typename(b) = "Variant()" then b = ln_hpdist(x, b)
lnmove = Array(x(0) - sin(lnslope(x)) * b, x(1) + cos(lnslope(x)) * b, x(2) - sin(lnslope(x)) * b, x(3) + cos(lnslope(x)) * b)
end function
Dim line, F
Dim l1, p2
With CreateObject("Scripting.FileSystemObject")
With .OpenTextFile("myfiles")
Do While Not .AtEndOfStream
line = .ReadLine: F = reSplit(line)
if reTest("^[ ]",line) then l1 = F '指示線
if reTest("^hp2",line) then p2 = Array(F(1),F(2))
Loop
End With
End With
Dim i
for i = 0 to 3
l1(i) = Cdbl(l1(i))
next
p2(0)=Cdbl(p2(0))
p2(1)=Cdbl(p2(1))
WScript.Echo "bz"
WScript.Echo Join(lnmove(l1, p2))